Nsryjdtyk

Now I'm trying to write a DM script to display a floating palette as shown in the following code. However, for example, a long string label as included in this code protrude from the palette window. So, I'm wondering how to change the palette window size (i.e, width in this case). Actually, some Gatan's official palette windows such as "Camera View", "Camera Acquire" etc. seem to be wider than the pallete created by this code. It will be appreciated if you share some wisdom. Thank you very much in advance.

Class MyDialog: UIFrame

{

    TagGroup createDLGtgs( Object self ){

        TagGroup DLGtgs, DLGItems

        DLGtgs = DLGCreateDialog( "Test Dialog", DLGItems )

        DLGItems.DLGAddElement( DLGCreateLabel( "Test of Gatan DigitalMicrograph scripting" ) )

        DLGItems.DLGAddElement( DLGCreatePushButton( "OK", "testOK" ) )

        return DLGtgs

    }

//

    Object Init( Object self ){

        self.super.Init( self.createDLGtgs() )

        return self

    }

//

    Void testOK( Object self ){

        OKDialog( "Hello!" )

    }

}

//

Object DialogOBJ = Alloc( MyDialog ).Init()

String DialogName = "Test Dialog"

String toolName = "Test Tool"

RegisterScriptPalette( DialogOBJ, DialogName, toolName )

OpenGadgetPanel(toolName)

Be aware that the situation of floating palettes is different between GMS 2.x and GMS 3.x.

Essentially, registered floating palettes are phased out in GMS 3.x with the new UI. They are still supported to some extend, but not all functionality remains and some behavior is buggy. For GMS 3.x it is generally better to launch scripted dialogs as modal or modeless dialogs and no longer install them as palettes.

This answer here is for GMS 2.x (Tested with GMS 2.3.3)

You need to add position tags to the dialog-describing tagGroup. You do this in your example code of the question above by adding to the TagGroup createDLGtgs( Object self ) method:

TagGroup positionTgs = DLGBuildPositionFromApplication()

positionTgs.TagGroupSetTagAsString( "Width", "Medium" ) 

DLGtgs.DLGPosition( positionTgs )

The string values accepted are:

• 
  "Small" Like the left-hand tool palettes of GMS 2.x.


• 
  "Medium" Like the right-hand tool palettes of GMS 2.x


• 
  "Wide" extra wide

There are, however, a few addtional options for the position tags, but they will not apply to floating palettes, just to regular modeless dialogs. You can set the width and height of a window either with an absolute size value or let it be automatically determined by the size of the content. Here is an example:

class CMyClass : UIFrame

{

    void InitAndShow( object self ) {

        Taggroup DLG,DLGItems

        DLG = DLGCreateDialog("Test",DLGItems)

        DLGItems.DLGAddElement( DLGCreateLabel( "Just some long text for extra width" ))

        DLGItems.DLGAddElement( DLGCreateLabel( "A second line" ))



        TagGroup positionTgs = DLGBuildPositionFromApplication()

        positionTgs.TagGroupSetTagAsTagGroup( "Width", DLGBuildAutoSize() )

        positionTgs.TagGroupSetTagAsTagGroup( "Height", DLGBuildAbsoluteSize( 45, "pixel" ) )

        DLG.DLGPosition( positionTgs )



        self.super.Init( DLG ).Display("Test")

    }

}



Alloc(CMyClass).InitAndShow()

In the above DLGBuildPositionFromApplication() sets the application window as the reference frame for the dialog. One can then define the position of the dialog left|center|right and top|center|bottom to that frame using the command DLGBuildRelativePosition() with -1|0|1 as respective parameter, like in the example:

class CMyClass : UIFrame

{

    void InitAndShow( object self ) {

        Taggroup DLG,DLGItems

        DLG = DLGCreateDialog("Test",DLGItems)

        DLGItems.DLGAddElement( DLGCreateLabel( "Just some long text for extra width" ))

        DLGItems.DLGAddElement( DLGCreateLabel( "A second line" ))



        TagGroup positionTgs = DLGBuildPositionFromApplication()

        positionTgs.TagGroupSetTagAsTagGroup( "Width", DLGBuildAutoSize() )

        positionTgs.TagGroupSetTagAsTagGroup( "Height", DLGBuildAutoSize() )



        // Appear top-right     

        positionTgs.TagGroupSetTagAsTagGroup( "X", DLGBuildRelativePosition( "Inside", 1 ) )

        positionTgs.TagGroupSetTagAsTagGroup( "Y", DLGBuildRelativePosition( "Inside", -1 ) )

        DLG.DLGPosition( positionTgs )



        self.super.Init( DLG ).Display("Test")

    }

}



Alloc(CMyClass).InitAndShow()

The reference-frame does not have to be the application window, though. You can specify any wanted using DLGBuildPosition(), which allows using f.e. a window rect and then placing the dialog right of it. And with the reference-frame, one can also size the dialog window relative to that using DLGBuildMatchSize() as in the following example:

class CMyClass : UIFrame

{

    void InitAndShow( object self, documentWindow win ) {

        Taggroup DLG,DLGItems

        DLG = DLGCreateDialog("Test",DLGItems)

        DLGItems.DLGAddElement( DLGCreateLabel( "Just some long text for extra width" ))

        DLGItems.DLGAddElement( DLGCreateLabel( "A second line" ))



        number t,l,b,r

        win.WindowGetFrameBounds(t,l,b,r)

        TagGroup positionTgs = DLGBuildPosition(t,l,b,r)

        positionTgs.TagGroupSetTagAsTagGroup( "Width", DLGBuildAutoSize() )

        positionTgs.TagGroupSetTagAsTagGroup( "Height", DLGBuildMatchSize() )



        // Appear center-right outside the window

        positionTgs.TagGroupSetTagAsTagGroup( "X", DLGBuildRelativePosition( "Outside", 1 ) )

        positionTgs.TagGroupSetTagAsTagGroup( "Y", DLGBuildRelativePosition( "Inside", 0 ) )

        DLG.DLGPosition( positionTgs )



        self.super.Init( DLG ).Display("Test")

    }

}



image img := RealImage("test",4,100,100)

img.ShowImage()

documentWindow win = img.ImageGetOrCreateImageDocument().ImageDocumentGetWindow()

Alloc(CMyClass).InitAndShow(win)